Cross compiling page in techbase

[Alexander Neundorf]

On Thursday 13 March 2008, Carlo wrote:
> On Thu, Mar 13, 2008 at 7:07 PM, Alexander Neundorf <neundorf at kde.org> 
wrote:
> > On Thursday 13 March 2008, Carlo wrote:
> >  > On Thu, Mar 13, 2008 at 1:11 AM, Alexander Neundorf <neundorf at kde.org>
> >
> >  wrote:
> >  ...
> >
> > > >  Is that using the modified FindKDE4.cmake ?
> > > >
> >  > >  mingw32-kdelibs.cmake sets KDE4_DATA_DIR, and if this is set,
> >  > > FindKDE4.cmake should use it to load FindKDE4Internal.cmake, which
> >  > > will load
> >  > >  KDELibsDependencies.cmake, which contains all these settings from
> >  > > the installed kdelibs.
> >  > >
> >  > >  What is going wrong ?
> >  > >  How does the installed KDELibsDependencies.cmake look like, i.e.
> >  > > are the paths in that file the same as the real locations ?
> >  >
> >  > Yes it uses the modified FindKDE4.cmake  and KDE4_DATA_DIR is set
> >  > the problem is that  KDELibsDependencies.cmake uses
> >  > ${KDE4_INSTALL_DIR} that is retrieved from this code
> >  > get_filename_component(_DIR ${KDE4_KDECONFIG_EXECUTABLE} PATH )
> >  > get_filename_component(KDE4_INSTALL_DIR ${_DIR} PATH )
> >  > but KDE4_KDECONFIG_EXECUTABLE is setted to the linux one, if i set it
> >  > to the windows one it goes ahead and it find include and library dir
> >  > but it doesn't find kde4automoc and kconfig_compiler
> >  > -- Found KDE 4.1 include dir: /windows/kde4/include
> >  > -- Found KDE 4.1 library dir: /windows/kde4/lib
> >  > -- Didn't find the KDE4 kconfig_compiler preprocessor
> >  > -- Didn't find the KDE4 automoc
> >
> >  Please update your FindKDE4Internal.cmake, I committed a change so that
> > now KDE4_INSTALL_DIR is determined relative to the location of the
> > installed FindKDE4Internal.cmake instead of kde4-config.exe. This should
> > help for now for this problem.

Please update FindKDE4Internal.cmake again, I reverted the change and modified 
FindKDE4.cmake from cmake instead.
Now you just have to make ure that kde4-config from the windows build is 
found. Then it should also find the rest.
This should work, your CMAKE_FIND_ROOT_PATH is set correctly.

Alex
-------------- next part --------------
# Find KDE4 and provide all necessary variables and macros to compile software for it.
# It looks for KDE 4 in the following directories in the given order:
#  CMAKE_INSTALL_PREFIX
#  KDEDIRS
#  /opt/kde4
#
# Please look in FindKDE4Internal.cmake and KDE4Macros.cmake for more information.
# They are installed with the KDE 4 libraries in $KDEDIRS/share/apps/cmake/modules/.
#
# Author: Alexander Neundorf <neundorf at kde.org>

FILE(TO_CMAKE_PATH "$ENV{KDEDIRS}" _KDEDIRS)

# when cross compiling, searching kde4-config in order to run it later on
# doesn't make a lot of sense. We'll have to do something about this. 
# Searching always in the target environment ? Then we get at least the correct one,
# still it can't be used to run it. Alex

# For KDE4 kde-config has been renamed to kde4-config
FIND_PROGRAM(KDE4_KDECONFIG_EXECUTABLE NAMES kde4-config
   PATH_SUFFIXES bin               # the suffix is for the paths coming from KDEDIRS
   PATHS
   ${CMAKE_INSTALL_PREFIX}
   ${_KDEDIRS}
   /opt/kde4
   NO_DEFAULT_PATH
   ONLY_CMAKE_FIND_ROOT_PATH
   )

FIND_PROGRAM(KDE4_KDECONFIG_EXECUTABLE NAMES kde4-config ONLY_CMAKE_FIND_ROOT_PATH)

IF (NOT KDE4_KDECONFIG_EXECUTABLE)
   IF (KDE4_FIND_REQUIRED)
      MESSAGE(FATAL_ERROR "ERROR: Could not find KDE4 kde4-config")
   ENDIF (KDE4_FIND_REQUIRED)
ENDIF (NOT KDE4_KDECONFIG_EXECUTABLE)


# when cross compiling, it may be already preset
IF(NOT KDE4_DATA_DIR)
   IF(CMAKE_CROSSCOMPILING)
      # when cross compiling, don't run kde4-config but use its location as install dir
      GET_FILENAME_COMPONENT(KDE4_DATA_DIR "${KDE4_KDECONFIG_EXECUTABLE}" PATH)
      GET_FILENAME_COMPONENT(KDE4_DATA_DIR "${KDE4_DATA_DIR}" PATH)
   ELSE(CMAKE_CROSSCOMPILING)

      # then ask kde4-config for the kde data dirs
      EXECUTE_PROCESS(COMMAND "${KDE4_KDECONFIG_EXECUTABLE}" --path data OUTPUT_VARIABLE _data_DIR ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
      FILE(TO_CMAKE_PATH "${_data_DIR}" _data_DIR)
      # then check the data dirs for FindKDE4Internal.cmake
      FIND_PATH(KDE4_DATA_DIR cmake/modules/FindKDE4Internal.cmake ${_data_DIR})
   ENDIF(CMAKE_CROSSCOMPILING)
ENDIF(NOT KDE4_DATA_DIR)

# if it has been found...
IF (KDE4_DATA_DIR)

   SET(CMAKE_MODULE_PATH  ${CMAKE_MODULE_PATH} ${KDE4_DATA_DIR}/cmake/modules)

   IF (KDE4_FIND_QUIETLY)
      SET(_quiet QUIET)
   ENDIF (KDE4_FIND_QUIETLY)

   IF (KDE4_FIND_REQUIRED)
      SET(_req REQUIRED)
   ENDIF (KDE4_FIND_REQUIRED)

   # use FindKDE4Internal.cmake to do the rest
   FIND_PACKAGE(KDE4Internal ${_req} ${_quiet})
ELSE (KDE4_DATA_DIR)
   IF (KDE4_FIND_REQUIRED)
      MESSAGE(FATAL_ERROR "ERROR: cmake/modules/FindKDE4Internal.cmake not found in ${_data_DIR}")
   ENDIF (KDE4_FIND_REQUIRED)
ENDIF (KDE4_DATA_DIR)