Seg fault - i965: Failed to submit batchbuffer: Input/output error

[Ralf Mardorf]

On Sun, 14 Jun 2020 11:18:05 +0200, Boudewijn Rempt wrote:
>Is this with an appimage or with the arch build?

Hi,

it's from the Arch package,
https://www.archlinux.org/packages/extra/x86_64/krita/ .




[rocketmouse at archlinux tmp]$ asp checkout krita
Cloning into 'krita'...
done.
[rocketmouse at archlinux tmp]$ cat krita/repos/extra-x86_64/PKGBUILD 
# Maintainer: Antonio Rojas <arojas at archlinux,org>

pkgname=krita
pkgver=4.2.9
pkgrel=6
pkgdesc="Edit and paint images"
arch=(x86_64)
url="https://krita.org"
license=(GPL3)
depends=(kitemviews kitemmodels ki18n kcompletion karchive kguiaddons kcrash qt5-svg qt5-multimedia quazip
         gsl libraw exiv2 openexr fftw boost-libs giflib hicolor-icon-theme)
makedepends=(extra-cmake-modules kdoctools boost eigen vc poppler-qt5 opencolorio python-pyqt5 libheif
             qt5-tools sip python-sip)
optdepends=('poppler-qt5: PDF filter' 'ffmpeg: to save animations' 'opencolorio: for the LUT docker'
            "krita-plugin-gmic: G'MIC plugin" 'python-pyqt5: for the Python plugins' 'libheif: HEIF filter')
conflicts=(calligra-krita krita-l10n)
replaces=(calligra-krita krita-l10n)
source=("https://download.kde.org/stable/krita/$pkgver/$pkgname-$pkgver.tar.gz"{,.sig}
         krita-pyqt5-sip5.patch
         krita-deadlock-qt5.14.2.patch::"https://invent.kde.org/kde/krita/commit/afed6a9e.patch"
         krita-qt-5.15.patch::"https://invent.kde.org/graphics/krita/-/commit/d5bb12ac.patch")
sha256sums=('9f85bb81eaf4976af57352a482af1fdb86f338051a991f6f43976e0b65956da8'
            'SKIP'
            'ab2f33843d8cad31bc13e0eca7dc732cdbfed054924f25ed61102c0d0971c1d8'
            '6477ceec976d376172cc82a5a8bf85938a7dffd924286fa79e64ccdab8c901eb'
            '8fac35357e6f69f919d47e600cc6dff64f08665bed4853219043949032e19370')
validpgpkeys=('05D00A8B73A686789E0A156858B9596C722EA3BD') # Boudewijn Rempt <foundation at krita.org>

prepare() {
  mkdir -p build

  cd $pkgname-$pkgver
  patch -p1 -i ../krita-pyqt5-sip5.patch # Fix sip include dir when PyQt5 is compiled with SIP 5
  patch -p1 -i ../krita-deadlock-qt5.14.2.patch # Fix deadlock on plugin load with Qt 5.14.2
  patch -p1 -i ../krita-qt-5.15.patch # Fix build with Qt 5.15
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DBUILD_TESTING=OFF \
    -DBUILD_KRITA_QT_DESIGNER_PLUGINS=ON
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}
[rocketmouse at archlinux tmp]$ cat krita/repos/extra-x86_64/krita-pyqt5-sip5.patch 
diff --git a/cmake/modules/FindPyQt5.py b/cmake/modules/FindPyQt5.py
index 5849f40868..a42ba6c624 100644
--- a/cmake/modules/FindPyQt5.py
+++ b/cmake/modules/FindPyQt5.py
@@ -2,7 +2,7 @@
 # Redistribution and use is allowed according to the terms of the BSD license.
 # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
 
-import sys
+import sys, site
 import os
 
 try:
@@ -41,7 +41,7 @@ except ValueError:
     pass
 
 # FIXME This next line is just a little bit too crude.
-pyqt_sip_dir = os.path.join(sys.prefix, "share", "sip", "PyQt5")
+pyqt_sip_dir = os.path.join(site.getsitepackages()[0], "PyQt5", "bindings")
 print("pyqt_sip_dir:%s" % pyqt_sip_dir)
 
 print("pyqt_sip_flags:%s" % PyQt5.QtCore.PYQT_CONFIGURATION["sip_flags"])




>And can you provide a stacktrace?

I'm sorry, but I can't. I need to get my work done and will not reboot
into a 5.7+ kernel.

Regards,
Ralf