[libstreamanalyzer] /: Switch to the new unified FindFFmpeg.cmake file.
Michael Jansen
kde at michael-jansen.biz
Tue Jun 28 20:56:33 CEST 2011
Git commit bb733a4fa0494ac4ca0303a2819746e87da7c875 by Michael Jansen.
Committed on 28/06/2011 at 20:58.
Pushed by mjansen into branch 'master'.
Switch to the new unified FindFFmpeg.cmake file.
CCMAIL: kde-buildsystem at kde.org
CCMAIL: strigi-devel at lists.sourceforge.net
M +1 -1 CMakeLists.txt
D +0 -213 cmake/FindFFMPEG.cmake
A +146 -0 cmake/FindFFmpeg.cmake
http://commits.kde.org/libstreamanalyzer/bb733a4fa0494ac4ca0303a2819746e87da7c875
diff --git a/CMakeLists.txt b/CMakeLists.txt
index d75dd66..ebc1905 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -83,7 +83,7 @@ find_package(Boost REQUIRED)
find_optional_dep(CLucene ENABLE_CLUCENE CLucene_FOUND "CLucene backend")
find_optional_dep(CLucene1 ENABLE_CLUCENE_NG CLUCENE1_FOUND "CLucene Version 1+ backend")
find_optional_dep(Exiv2 ENABLE_EXIV2 EXIV2_FOUND "indexing of EXIF/IPTC metadata")
-find_optional_dep(FFMPEG ENABLE_FFMPEG FFMPEG_FOUND "indexing FFMPEG")
+find_optional_dep(FFmpeg ENABLE_FFMPEG FFMPEG_FOUND "indexing FFMPEG" COMPONENTS AVCODEC AVFORMAT AVUTIL SWSCALE)
find_package(XAttr)
include(ConfigureChecks.cmake)
configure_file(LibStreamAnalyzer.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/LibStreamAnalyzerConfig.cmake @ONLY )
diff --git a/cmake/FindFFMPEG.cmake b/cmake/FindFFMPEG.cmake
deleted file mode 100644
index 14798a3..0000000
--- a/cmake/FindFFMPEG.cmake
+++ /dev/null
@@ -1,213 +0,0 @@
-# - Try to find FFMPEG
-# Once done this will define
-#
-# FFMPEG_FOUND - system has FFMPEG
-# FFMPEG_INCLUDE_DIRS - the FFMPEG include directory
-# FFMPEG_LIBRARIES - Link these to use FFMPEG
-# FFMPEG_DEFINITIONS - Compiler switches required for using FFMPEG
-#
-# Copyright (c) 2008 Andreas Schneider <mail at cynapses.org>
-# Copyright (c) 2010 Christophe Giboudeaux <cgiboudeaux at gmail.com>
-#
-# Redistribution and use is allowed according to the terms of the New
-# BSD license.
-# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
-#
-
-if (FFMPEG_LIBRARIES AND FFMPEG_INCLUDE_DIRS)
- # in cache already
- set(FFMPEG_FOUND TRUE)
-else (FFMPEG_LIBRARIES AND FFMPEG_INCLUDE_DIRS)
-
- # use pkg-config to get the directories and then use these values
- # in the FIND_PATH() and FIND_LIBRARY() calls
- if (NOT WIN32)
- include(FindPkgConfig)
- pkg_check_modules(_AVCODEC libavcodec)
- pkg_check_modules(_AVFORMAT libavformat)
- pkg_check_modules(_AVUTIL libavutil)
- #pkg_check_modules(_POSTPROC libpostproc)
- pkg_check_modules(_SWSCALE libswscale)
-
- endif (NOT WIN32)
-
- find_library(AVCODEC_LIBRARY
- NAMES
- avcodec
- PATHS
- ${_AVCODEC_LIBDIR}
- /usr/lib
- /usr/local/lib
- /opt/local/lib
- /sw/lib
- NO_DEFAULT_PATH
- )
-
- find_path(AVCODEC_INCLUDE_DIR
- NAMES
- avcodec.h
- PATHS
- ${_AVCODEC_INCLUDEDIR}
- /usr/include
- /usr/local/include
- /opt/local/include
- /sw/include
- PATH_SUFFIXES
- libavcodec
- ffmpeg
- NO_DEFAULT_PATH
- )
-
- if(AVCODEC_LIBRARY AND AVCODEC_INCLUDE_DIR)
- set(AVCODEC_FOUND TRUE)
- mark_as_advanced(AVCODEC_LIBRARY AVCODEC_INCLUDE_DIR)
- endif(AVCODEC_LIBRARY AND AVCODEC_INCLUDE_DIR)
-
- find_library(AVFORMAT_LIBRARY
- NAMES
- avformat
- PATHS
- ${_AVFORMAT_LIBDIR}
- /usr/lib
- /usr/local/lib
- /opt/local/lib
- /sw/lib
- NO_DEFAULT_PATH
- )
-
- find_path(AVFORMAT_INCLUDE_DIR
- NAMES
- avformat.h
- PATHS
- ${_AVFORMAT_INCLUDEDIR}
- /usr/include
- /usr/local/include
- /opt/local/include
- /sw/include
- PATH_SUFFIXES
- libavformat
- ffmpeg
- NO_DEFAULT_PATH
- )
-
- if(AVFORMAT_LIBRARY AND AVFORMAT_INCLUDE_DIR)
- set(AVFORMAT_FOUND TRUE)
- mark_as_advanced(AVFORMAT_LIBRARY AVFORMAT_INCLUDE_DIR)
- endif(AVFORMAT_LIBRARY AND AVFORMAT_INCLUDE_DIR)
-
- find_library(AVUTIL_LIBRARY
- NAMES
- avutil
- PATHS
- ${_AVUTIL_LIBDIR}
- /usr/lib
- /usr/local/lib
- /opt/local/lib
- /sw/lib
- NO_DEFAULT_PATH
- )
- mark_as_advanced(AVUTIL_LIBRARY)
-
- find_path(AVUTIL_INCLUDE_DIR
- NAMES
- avutil.h
- PATHS
- ${_AVUTIL_INCLUDEDIR}
- /usr/include
- /usr/local/include
- /opt/local/include
- /sw/include
- PATH_SUFFIXES
- libavutil
- ffmpeg
- NO_DEFAULT_PATH
- )
-
- if(AVUTIL_LIBRARY AND AVUTIL_INCLUDE_DIR)
- set(AVUTIL_FOUND TRUE)
- mark_as_advanced(AVUTIL_LIBRARY AVUTIL_INCLUDE_DIR)
- endif(AVUTIL_LIBRARY AND AVUTIL_INCLUDE_DIR)
-
- find_library(SWSCALE_LIBRARY
- NAMES
- swscale
- PATHS
- ${_SWSCALE_LIBDIR}
- /usr/lib
- /usr/local/lib
- /opt/local/lib
- /sw/lib
- NO_DEFAULT_PATH
- )
-
- find_path(SWSCALE_INCLUDE_DIR
- NAMES
- swscale.h
- PATHS
- ${_SWSCALE_INCLUDEDIR}
- /usr/include
- /usr/local/include
- /opt/local/include
- /sw/include
- PATH_SUFFIXES
- libswscale
- ffmpeg
- NO_DEFAULT_PATH
- )
-
- if(SWSCALE_LIBRARY AND SWSCALE_INCLUDE_DIR)
- set(SWSCALE_FOUND TRUE)
- mark_as_advanced(SWSCALE_LIBRARY SWSCALE_INCLUDE_DIR)
- endif(SWSCALE_LIBRARY AND SWSCALE_INCLUDE_DIR)
-
- # find_library(POSTPROC_LIBRARY
- # NAMES
- # postproc
- # PATHS
- # ${_POSTPROC_LIBDIR}
- # /usr/lib
- # /usr/local/lib
- # /opt/local/lib
- # /sw/lib
- # NO_DEFAULT_PATH
- # )
- # mark_as_advanced(POSTPROC_LIBRARY)
-
- # find_path(POSTPROC_INCLUDE_DIR
- # NAMES
- # postprocess.h
- # PATHS
- # ${_POSTPROC_INCLUDEDIR}
- # /usr/include/postproc
- # /usr/local/include/postproc
- # /opt/local/include/postproc
- # /sw/include
- # PATH_SUFFIXES
- # libpostproc
- # ffmpeg
- # )
- # mark_as_advanced(POSTPROC_INCLUDE_DIR)
-
- # if(POSTPROC_LIBRARY AND POSTPROC_INCLUDE_DIR)
- # set(SWSCALE_FOUND TRUE)
- # mark_as_advanced(POSTPROC_LIBRARY POSTPROC_INCLUDE_DIR)
- # endif(POSTPROC_LIBRARY AND POSTPROC_INCLUDE_DIR)
-
- if(AVCODEC_FOUND AND AVFORMAT_FOUND AND AVUTIL_FOUND AND SWSCALE_FOUND)
- set (FFMPEG_LIBRARIES
- ${AVCODEC_LIBRARY}
- ${AVFORMAT_LIBRARY}
- ${AVUTIL_LIBRARY}
- ${SWSCALE_LIBRARY}
- )
- set(FFMPEG_INCLUDE_DIRS
- ${AVCODEC_INCLUDE_DIR}
- ${AVFORMAT_INCLUDE_DIR}
- ${AVUTIL_INCLUDE_DIR}
- ${SWSCALE_INCLUDE_DIR}
- )
- set(FFMPEG_FOUND TRUE)
- mark_as_advanced(FFMPEG_INCLUDE_DIRS FFMPEG_LIBRARIES)
- endif(AVCODEC_FOUND AND AVFORMAT_FOUND AND AVUTIL_FOUND AND SWSCALE_FOUND)
-
-endif (FFMPEG_LIBRARIES AND FFMPEG_INCLUDE_DIRS)
diff --git a/cmake/FindFFmpeg.cmake b/cmake/FindFFmpeg.cmake
new file mode 100644
index 0000000..f4e57cd
--- /dev/null
+++ b/cmake/FindFFmpeg.cmake
@@ -0,0 +1,146 @@
+# vim: ts=2 sw=2
+# - Try to find the required ffmpeg components(default: AVFORMAT, AVUTIL, AVCODEC)
+#
+# Once done this will define
+# FFMPEG_FOUND - System has the all required components.
+# FFMPEG_INCLUDE_DIRS - Include directory necessary for using the required components headers.
+# FFMPEG_LIBRARIES - Link these to use the required ffmpeg components.
+# FFMPEG_DEFINITIONS - Compiler switches required for using the required ffmpeg components.
+#
+# For each of the components it will additionaly set.
+# - AVCODEC
+# - AVDEVICE
+# - AVFORMAT
+# - AVUTIL
+# - POSTPROCESS
+# - SWSCALE
+# the following variables will be defined
+# <component>_FOUND - System has <component>
+# <component>_INCLUDE_DIRS - Include directory necessary for using the <component> headers
+# <component>_LIBRARIES - Link these to use <component>
+# <component>_DEFINITIONS - Compiler switches required for using <component>
+# <component>_VERSION - The components version
+#
+# Copyright (c) 2006, Matthias Kretz, <kretz at kde.org>
+# Copyright (c) 2008, Alexander Neundorf, <neundorf at kde.org>
+# Copyright (c) 2011, Michael Jansen, <kde at michael-jansen.biz>
+#
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+
+include(FindPackageHandleStandardArgs)
+
+# The default components were taken from a survey over other FindFFMPEG.cmake files
+if (NOT FFmpeg_FIND_COMPONENTS)
+ set(FFmpeg_FIND_COMPONENTS AVCODEC AVFORMAT AVUTIL)
+endif ()
+
+#
+### Macro: set_component_found
+#
+# Marks the given component as found if both *_LIBRARIES AND *_INCLUDE_DIRS is present.
+#
+macro(set_component_found _component )
+ if (${_component}_LIBRARIES AND ${_component}_INCLUDE_DIRS)
+ # message(STATUS " - ${_component} found.")
+ set(${_component}_FOUND TRUE)
+ else ()
+ # message(STATUS " - ${_component} not found.")
+ endif ()
+endmacro()
+
+#
+### Macro: find_component
+#
+# Checks for the given component by invoking pkgconfig and then looking up the libraries and
+# include directories.
+#
+macro(find_component _component _pkgconfig _library _header)
+
+ if (NOT WIN32)
+ # use pkg-config to get the directories and then use these values
+ # in the FIND_PATH() and FIND_LIBRARY() calls
+ find_package(PkgConfig)
+ if (PKG_CONFIG_FOUND)
+ pkg_check_modules(PC_${_component} ${_pkgconfig})
+ endif ()
+ endif (NOT WIN32)
+
+ find_path(${_component}_INCLUDE_DIRS ${_header}
+ HINTS
+ ${PC_LIB${_component}_INCLUDEDIR}
+ ${PC_LIB${_component}_INCLUDE_DIRS}
+ )
+
+ find_library(${_component}_LIBRARIES NAMES ${_library}
+ HINTS
+ ${PC_LIB${_component}_LIBDIR}
+ ${PC_LIB${_component}_LIBRARY_DIRS}
+ )
+
+ set(${_component}_DEFINITIONS ${PC_${_component}_CFLAGS_OTHER} CACHE STRING "The ${_component} CFLAGS.")
+ set(${_component}_VERSION ${PC_${_component}_VERSION} CACHE STRING "The ${_component} version number.")
+
+ set_component_found(${_component})
+
+ mark_as_advanced(
+ ${_component}_INCLUDE_DIRS
+ ${_component}_LIBRARIES
+ ${_component}_DEFINITIONS
+ ${_component}_VERSION)
+
+endmacro()
+
+
+# Check for cached results. If there are skip the costly part.
+if (NOT FFMPEG_LIBRARIES)
+
+ # Check for all possible component.
+ find_component(AVCODEC libavcodec avcodec libavcodec/avcodec.h)
+ find_component(AVFORMAT libavformat avformat libavformat/avformat.h)
+ find_component(AVDEVICE libavdevice avdevice libavdevice/avdevice.h)
+ find_component(AVUTIL libavutil avutil libavutil/avutil.h)
+ find_component(SWSCALE libswscale swscale libswscale/swscale.h)
+ find_component(POSTPROC libpostproc postproc libpostproc/postprocess.h)
+
+ # Check if the required components were found and add their stuff to the FFMPEG_* vars.
+ foreach (_component ${FFmpeg_FIND_COMPONENTS})
+ if (${_component}_FOUND)
+ # message(STATUS "Required component ${_component} present.")
+ set(FFMPEG_LIBRARIES ${FFMPEG_LIBRARIES} ${${_component}_LIBRARIES})
+ set(FFMPEG_DEFINITIONS ${FFMPEG_DEFINITIONS} ${${_component}_DEFINITIONS})
+ list(APPEND FFMPEG_INCLUDE_DIRS ${${_component}_INCLUDE_DIRS})
+ else ()
+ # message(STATUS "Required component ${_component} missing.")
+ endif ()
+ endforeach ()
+
+ # Build the include path with duplicates removed.
+ if (FFMPEG_INCLUDE_DIRS)
+ list(REMOVE_DUPLICATES FFMPEG_INCLUDE_DIRS)
+ endif ()
+
+ # cache the vars.
+ set(FFMPEG_INCLUDE_DIRS ${FFMPEG_INCLUDE_DIRS} CACHE STRING "The FFmpeg include directories." FORCE)
+ set(FFMPEG_LIBRARIES ${FFMPEG_LIBRARIES} CACHE STRING "The FFmpeg libraries." FORCE)
+ set(FFMPEG_DEFINITIONS ${FFMPEG_DEFINITIONS} CACHE STRING "The FFmpeg cflags." FORCE)
+
+ mark_as_advanced(FFMPEG_INCLUDE_DIRS
+ FFMPEG_LIBRARIES
+ FFMPEG_DEFINITIONS)
+
+endif ()
+
+# Now set the noncached _FOUND vars for the components.
+foreach (_component AVCODEC AVDEVICE AVFORMAT AVUTIL POSTPROCESS SWSCALE)
+ set_component_found(${_component})
+endforeach ()
+
+# Compile the list of required vars
+set(_FFmpeg_REQUIRED_VARS FFMPEG_LIBRARIES FFMPEG_INCLUDE_DIRS)
+foreach (_component ${FFmpeg_FIND_COMPONENTS})
+ list(APPEND _FFmpeg_REQUIRED_VARS ${_component}_LIBRARIES ${_component}_INCLUDE_DIRS)
+endforeach ()
+
+# Give a nice error message if some of the required vars are missing.
+find_package_handle_standard_args(FFmpeg DEFAULT_MSG ${_FFmpeg_REQUIRED_VARS})
More information about the Kde-buildsystem
mailing list