<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<xsl:output method="html"/>
<xsl:template match="/">
<html>
<head><link rel="stylesheet" href="style.css"/></head>
<body>
<div id="sidebar">
<xsl:apply-templates mode="sidebar"/></div>
<div id="maintext">
<xsl:apply-templates/></div>
</body>
</html>
</xsl:template>
<xsl:template match="release" mode="sidebar">
<a class="sidebarentry" href="#{@version}">
KDE <xsl:value-of select="@version"/></a>
<a class="sidebarentry1" href="#{@version}-features">Features</a>
<a class="sidebarentry1" href="#{@version}-bugfixes">Bugfixes</a>
<a class="sidebarentry1" href="#{@version}-improvements">Improvements</a>
</xsl:template>
<xsl:template match="release">
<h1> <a>
<xsl:attribute name="name">
<xsl:value-of select="@version"/></xsl:attribute>
</a>
Changes in KDE <xsl:value-of select="@version"/></h1>
<h2><a name="{@version}-features"/>
New Features</h2>
<xsl:apply-templates select=".//feature"/>
<h2><a name="{@version}-improvements"/>Improvements</h2>
<xsl:apply-templates select=".//improvement"/>
<h2><a name="{@version}-bugfixes"/>Bugfixes</h2>
<xsl:apply-templates select=".//bugfix"/>
</xsl:template>
<xsl:template match="improvement">
<div class="improvement"><span class="prodname"><xsl:value-of select="ancestor::product/@name"/>:</span><xsl:apply-templates/></div>
</xsl:template>
<xsl:template match="bugfix">
<div class="bugfix">
<span class="prodname"><xsl:value-of select="ancestor::product/@name"/>:</span>
<xsl:apply-templates/>
Fixes bug <a>
<xsl:attribute name="href">http://bugs.kde.org/show_bug.cgi?id=<xsl:value-of
select='@bugno'/></xsl:attribute>
<xsl:value-of select="@bugno"/>
</a>
</div>
</xsl:template>
<xsl:template match="feature">
<div class="feature"><span class="prodname"><xsl:value-of select="ancestor::product/@name"/>:</span><xsl:apply-templates/>
<xsl:if test="@bugno != ''">
As requested in bug <a>
<xsl:attribute name="href">http://bugs.kde.org/show_bug.cgi?id=<xsl:value-of
select='@bugno'/></xsl:attribute>
<xsl:value-of select="@bugno"/>
</a></xsl:if>
</div>
</xsl:template>
</xsl:stylesheet>